Previous Up Next

15  GROUP EX—EXAMPLES

EX.10


On the following pages the user may find some examples of input files. The examples are purely indicative of the ’flavour’ of the program. Much more examples could be found as benchmarks of the EUROPLEXUS consortium.


In addition, the user can find many actual EUROPLEXUS examples (including input, pre-treatment and post-treatment files) in some of the publications listed in the bibliography at the end of the present manual.


Unless it is specified otherwise, the mesh is created by means of GIBI. The GIBI data is given so as to define the objects without any ambiguity.

15.1  BENDING OF A BEAM

EX.20

This example is part of the EUROPLEXUS benchmarks and has the name bm_manex_01.


Object:


This is a 2D elastic computation.


A beam is subjected to an uniform stress (pressure).


Geometry and meshing :
L = 24.0 mm : half length of the beam;

e = 1.0 mm : thickness;

The mesh is entered in free format;

There are 12 "COQU" shell elements.


Physical properties:
rho = 8000 kg/m 3 : density;

nu = 0.3 : Poisson’s ratio;

E = 200 GPa : Young’s modulus.


Boundary conditions:


- The pressure increases from 0 to 2 MPa in 0.1 millisecond, then remains constant.


Clamped boundary and symmetry conditions are applied at the centre.


Computation:


The step is automatic and the computation ends at 0.01 s.


In order to visualize the results more easily, the computation is followed by the drawing of the time dependant displacement of the centre of the beam.


List of the input file:
VIBRATION   !Title - must be given!
!ECHO       !Output in the console
DPLA        !Two-dimensional plane strain computation
!
! Geometry
!
GEOM LIBR POIN 13 COQU 12 TERM           !Input of the geometry in free format
 0 0  2 0  4 0  6 0  8 0 10 0 12 0
14 0 16 0 18 0 20 0 22 0 24 0
1 2 2 3 3 4 4 5 5 6 6 7 7 8 8 9 9 10 10 11 11 12 12 13
COMP EPAI 1. LECT TOUS TERM              !Thickness of the shell elements
!
! Materials
!
MATE LINE RO 8E-9 YOUN 2E5 NU 0.3 LECT TOUS TERM
!
! Boundary Conditions
!
LINK COUP BLOQ 23 LECT  1 TERM
               13 LECT 13 TERM
CHAR 1 FACT 2 PRES COQU -2. LECT TOUS TERM  !Loading with a pressure
       TABL 3 0 0 1E-4 1 1 1                !Time depended variable for the pressure
!
! Outputs
!
ECRI VITE CONT ECRO TFRE 1.E-3            !Output into the listing
          POIN LECT 1 TERM
          ELEM LECT 1 TERM
     FICH ALIC TFRE 1E-4                  !Output into the alice file
     FICH PVTK TFRE 1E-4                  !Output into the ParaView file
               VARI ECRO CONT DEPL
!
! Options
!
OPTI NOTE
     LOG 1                                !log file is written for each time step
                                          !should not be done for MPI!
!
! Calculation Parameters
!
CALC TINI 0 TEND 10E-3                    !End of calculation at 10e-3 s
*=================================================================
SUIT
Post-Processing                           !Title
*
RESU ALIC GARD PSCR
SORT GRAP
*
AXTE 1E3 'TIME (MS)'
*
COUR 1 'COQU' DEPLA COMP 2 NOEU LECT 13 TERM
DESS 1 1 AXES 1. 'DEFLECTION (MM)'
*=================================================================
FIN

15.2  IMPACT ON A CIRCULAR PLATE

EX.30

This example is part of the EUROPLEXUS benchmarks and has the name bm_manex_02.


Object:


This is a 2D plastic computation.


A clamped plate is submitted to the impact of a rigid missile.


Geometry and meshing :
D = 465 mm : diameter of the plate

e = 6 mm : thickness


The missile is a flat nose cylinder, 90 mm in diameter. It falls straight in the middle of the plate.


The user wants to follow the displacements of point P1 to P4 whose location has been imposed.


GIBI data:
TITRE 'IMPACT SUR DES PLAQUES CIRCULAIRES' ;
OPTIO DIME 2 ELEM SEG2 ;
DPROJ=90; RPROJ=DPROJ / 2;
DENS 7;
CENTR= 0 0 ; BORD=RPROJ 0 ; BORD2=DPROJ 0 ; ENCAS=233.5 0 ;
   P1=60 0 ;   P2=80 0    ;    P3=120 0   ;    P4=160 0   ;
   P0= 0 0 ;
LIG1=CENTR DROIT BORD  ; LIG1=LIG1 COUL ROUG ;
LIG2=BORD  D  P1  D  P2  D  BORD2  D  P3  D  P4  D  ENCAS ;
LIG2=LIG2 COUL VERT ;
PLAQ=LIG1 ET LIG2 ;
PROJ=MANUEL POI1 P0;
MESH=PROJ ET PLAQ;
SORTIE MESH;
TASS MESH;
OPTI sauv form 'bm_manex_02.msh';
sauv form MESH;
FIN;

Physical properties:
rho = 7800 kg/m3 : density;

nu = 0.3 : Poisson’s ratio;

E = 230 GPa : Young’s modulus;

Y = 188 MPa : elastic limit.


Boundary conditions:


The missile has a mass of 257 kg, it falls at a speed of 11.38 m/s (be careful, the axisymmetric computation concerns ONE radian).


- Clamped boundary and symmetry conditions.


Computation:


The step is automatic and the computation concerns the first 12 milliseconds.


In order to visualize the results more easily, the computation is followed by three drawings:

- impulse of the missile

- displacements of the missile and the nodes submitted to the impact

- displacements of the center and the remarkable points


List of the input file:
--- IMPACT SUR DES PLAQUES CIRCULAIRES (E=6 D=90 M=257 VI=11.38)
ECHO
CAST MESH
AXIS
GEOM COQU PLAQ PMAT PROJ TERM
COMP
     EPAI   6 LECT PLAQ TERM
MATE VMIS ISOT RO 7.8E-9 YOUN 230E3 NU .3 ELAS 188
     TRAC 13  188   .0817E-2
              261   .2000E-2
              288   .3000E-2
              318   .4900E-2
              339   .7500E-2
              354  1.07E-2
              377  1.94E-2
              423  4.75E-2
              497  9.54E-2
              585 18.20E-2
              649 26.20E-2
              693 33.70E-2
              710 37.20E-2
     LECT PLAQ TERM
     MASS 40.903E-3    LECT PROJ TERM
INIT VITE 2 -11380 LECT PROJ TERM
LIAI BLOQ 123 LECT ENCAS TERM
          13 LECT CENTR TERM
      IMPACT DDL 2 COTE -1 PROJ  LECT PROJ TERM
                           CIBLE LECT LIG1 TERM
ECRI VITE CONT ECRO TFRE 1.E-3            !Output into the listing
          POIN LECT 1 TERM
          ELEM LECT 1 TERM
     FICH ALIC TFRE 1E-3                  !Output into the alice file
     FICH ALIT TFRE 1E-4 POIN LECT 11 16 21 23 25 31 32 TERM
OPTION NOTEST
CALCUL TINI 0 TEND 12.01E-3
SUIT
IMPACT SUR DES PLAQUES CIRCULAIRES (E=6 D=90 M=257 VI=11.38)
RESU ALIC GARD PSCR
SORT GRAP
AXTEMPS 1000 'TEMPS (MS)'
COURBE  1 'IMPULSION'  ECROU COMP 1 ELEM 31
     DESSIN 1  1                AXES   1. 'IMPUL. (N*S)'
COURBE  2 'D-PROJ'     DEPLA COMP 2 NOEU 32
COURBE  3 'D-CENTRE'   DEPLA COMP 2 NOEU 31
COURBE  4 'D-BORD'     DEPLA COMP 2 NOEU 25
COURBE  5 'D-60 (J1)'  DEPLA COMP 2 NOEU 23
COURBE  6 'D-80 (D1)'  DEPLA COMP 2 NOEU 21
COURBE  7 'D-120 (D2)' DEPLA COMP 2 NOEU 16
COURBE  8 'D-160 (D3)' DEPLA COMP 2 NOEU 11
     DESSIN 3  2 3 4            AXES   1. 'DEPLA (MM)'
     DESSIN 6  3 4 5 6 7 8      AXES   1. 'DEPLA (MM)'
FIN

15.3  EXPLOSION IN A TANK

EX.40


Object:


This is a 2-D computation in A.L.E.


A cylindrical tank is filled with water. At its center a micro charge of T.N.T. explodes. the development of a gas bubble (supposed perfect),and deformations of the cylinder may be observed.


Geometry and meshing:


Only one quarter of the tank is meshed. Water and gas are modelled by quadrilaterals and the cylinder by thin shell elements. There are also elements of fluid-structure interactions.

R = 0.19 m : radius of the cylinder;

H = 0.19 m : half height;

r = 0.299 m : initial radius of the bubble.


GIBI data:
TITRE 'MAILLAGE MANON';
OPTION DIME 2 ELEM QUA4;
RBUL=0.029947;RAY=0.19;
CB=0 0 ; FBR=RBUL 0; FLR=RAY 0;
FBZ=0 RBUL; FLZ=0 RAY;TOP=RAY RAY;
LBR=CB D 5 FBR;LLR=FBR D 12 FLR;
LBZ=CB D 5 FBZ;LLZ=FBZ D 12 FLZ;
AUX=RBUL*(SIN 45);P45=AUX AUX;
FB1=C 5 FBR CB P45;FB2=C 5 P45 CB FBZ;
FBUL=FB1 ET FB2;
BULLE=LBR FB1 FB2 LBZ DALLER PLAN;
TOIT=FLZ D 5 TOP;
SUR =FLR D 5 TOP;
SEP =P45 D 12 TOP;
LIQ1 =LLR SUR SEP FB1 DALLER PLAN;
LIQ2 =SEP TOIT LLZ FB2 DALLER PLAN;
EAU = LIQ1 ET LIQ2;
VA=0 0;CQ1=FLR PLUS VA;CQ2=TOP PLUS VA;
COQ=CQ1 D 5 CQ2;
RAC=RACCOR 0.001 SUR COQ;
PBUL=BULLE CHANGE POI1;
PBUL=PBUL DIFF ((FBUL CHANG POI1) ET CB);
PLIQ1=LIQ1 CHANGE POI1;
PLIQ1=PLIQ1 DIFF ((FB1 ET SEP ET SUR) CHANG POI1);
PLIQ2=LIQ2 CHANGE POI1;
PLIQ2=PLIQ2 DIFF (((FB2 ET SEP) CHANG POI1) ET FLZ);
PSEP=(SEP CHANG POI1) DIFF (TOP ET P45);
ZALE=PBUL ET PLIQ1 ET PLIQ2 ET PSEP;
TOUT=BULLE ET EAU ET RAC ET COQ ET ZALE;
SORTIE TOUT;
FIN;

Physical properties:

Water:
rho = 1000 Kg/m3 : density;

c = 1500 m/s : velocity of sound.


Bubble:
rho = 482 Kg/m3 : density;

pini = 288 MPa : initial pressure;

gamma = 1.535 : Cp/Cv ratio.


Cylinder:
rho = 7900 Kg/m3 : density;

E = 190 GPa : Young’s modulus;

nu = 0.3 : Poisson’s ratio;

elas = 265 MPa : elastic limit.


Boundary conditions:


- The upper part of the tank is very rigid, therefore displacements have been embedded along z.


Computation :


The step is automatic and the computation is done during the first two milliseconds.


In order to visualize the results more easily, the computation is followed by the drawing of the time dependant displacements of the generating line of the cylinder.


List of the input file:
TEST MANON 11 (1/4) ( IN A.L.E. WITH CAR4 ) !titre

echo
GIBI 9 TOUT
$TRAC
AXIS ALE
DIME
   BLOQ 50 RELA 1 2 NALE 200
TERM

GEOM CAR4 BULLE EAU COQU COQ FS2D RAC TERM

COMPL
   EPAIS 1.25E-3 LECT COQ TERM
GRILLE
   LAGRANGE LECT COQ FBUL TERM
   ALE      LECT BULLE EAU TERM
$ POUR LE CONTACT "FS"
       FS     LECT RAC TERM
$ POUR L'EAU
       LIGNE BASE LECT CQ2 P45 TERM
              LIST LECT PSEP TERM
       PLAN   BASE LECT CQ1 CQ2 P45 FBR TERM
              LIST LECT PLIQ1 TERM
       PLAN   BASE LECT CQ2 FLZ FBZ P45 TERM
              LIST LECT PLIQ2 TERM
$ POUR LA BULLE
       PLAN   BASE LECT CB FBR P45 FBZ TERM
              LIST LECT PBUL TERM

MATERIAUX
   VMIS ISOT RO 7900. YOUNG 190E9 NU .3 ELAS 265E6
        TRAC 5 265E6     .00139
                352E6    .0202
                481E6    .105
                559E6    .2214
                600E6    .349
        LECT COQ TERM
   FLUI RO 1000. C 1500. PINI 1E5 PREF 1E5 PMIN 0
        LECT EAU TERM
    GAZP RO 482. GAMMA 1.535 PINI 2.88E8 PREF 1E5
         LECT BULLE TERM
LINK RENUM
    BLOQ   1 LECT LBZ LLZ CQ2 TERM
           2 LECT TOIT LBR LLR TERM
          23 LECT CQ1 CQ2 TERM
ECRITURE
  TFREQ .25E-3     TRACE ALICE 10 TFREQ .5E-4
OPTION AUTO
        NOTEST
CALCUL tini 0  nmax  1000 tfin 1.005E-3
SUITE
TEST MANON 11 (1/4) ( EN A.L.E. AVEC CAR4 )
RESULT 10
TEMPS 100 COURBE 5 TERM
SORTIE GRAPHIQUE
AXTEMPS 1E3 'T (MILLISEC.)'
COURBE 1 'DR-00 '       DEPLA COMP 1 NOEUD 5
COURBE 2 'DR-38 '       DEPLA COMP 1 NOEUD 6
COURBE 3 'DR-76 '       DEPLA COMP 1 NOEUD 4
COURBE 4 'DR-114 '       DEPLA COMP 1 NOEUD 3
COURBE 5 'DR-152 '       DEPLA COMP 1 NOEUD 2
DESSIN 5       1 2 3 4 5    AXES 1000 'DR-COQUE (MM)'
FIN

15.4  MODELLING OF PERFORATED PLATES

EX.50


Object:


This is a 2-D computation in A.L.E.


A plane wave is propagating in a cylindrical tube. It meets a perforated plate that generates partial reflections and head losses. The walls of the cylinder are supposed rigid and the plate flexible.


Geometry and meshing:


Only the fluid in the tube is meshed. Elements with absorbant boundary conditions shall avoid reflected waves. At one end, a range of CL2D elements enables pressure source to be input in the form of a slope. These elements are superimposed to the absorbant elements.


The clamped plate is meshed with shell elements. The fluid is meshed in a continuous way to make it pass through the plate. The connecting elements of the fluid-structure junction ensure the coupling between the plate and the neighbouring nodes of the fluid. Another range of CL2D elements enables the characteristics of the grid to be input for the computation of the head losses.

R = 500 mm : radius of the cylinder;

H = 1000 mm : half height.


GIBI data:
TITRE 'MAILLAGE D'UNE PLAQUE PERFOREES';
OPTI DIME 2 ELEM QUA4 NIVEAU 1;
PA=0 0    ; PB=500 0   ; PC=500 2000 ; PD=0 2000;
PE=0 1000 ; PF=500 1000;
ENT=PA D 5 PB ; SOR=PC D 5 PD ;
GRI=PF D 5 PE ; ENT2=ENT ;
LBF=PB D 10 PF ; LFC=PF D 10 PC ;
LDE=PD D 10 PE ; LEA=PE D 10 PA ;
LIQ1=ENT LBF GRI LEA DALLER PLAN ;
LIQ2=(INVE GRI) LFC SOR LDE DALLER PLAN ;
LIQ=LIQ1 ET LIQ2 ;
PCE=0 1000 ; PCF=500 1000 ;
COQ=PCF D 5 PCE;
FSE=RACC 0.00001 LIQ1 COQ ;
PLIQ=LIQ CHAN POI1;
PLIQ=PLIQ DIFF (GRI CHAN POI1);
AXE=LDE ET LEA ET PCE ;
BOR=LBF ET LFC ET PCF ;
LIQ=LIQ COUL BLEU;COQ=COQ COUL ROUG;
FSE=FSE COUL TURQ;ENT2=ENT2 COUL VERT;
TOUT=LIQ ET COQ ET FSE ET PLIQ ET AXE ET BOR ET ENT2;
SORT TOUT;
fin;

Physical properties:

Fluid:
rho = 1000 Kg/m3 : density

c = 1000 m/s : velocity of sound


Plate:
rho = 7800 Kg/m3 : density

E = 190 GPa : Young’s modulus

nu = 0.3 : Poisson’s ratio


Computation:


The step is automatic and the computation is carried out for the first 6 milliseconds.


In order to visualize the results more easily, the computation is followed by two drawings. The first one describes the evolution of the pressures upstream and downstream, and the second describes the displacement of the center of the plate


List of the input file:
PLAQUE PERFOREE SOUPLE (EULER) ALP=1 TAU=0 E=15
ECHO
GIBI 9 TOUT
AXIS EULER
DIMENSION
     BLOQ 60 NALE 100
     TERM
GEOM CAR1 LIQ CL2D ENT SOR GRI ENT2 COQU COQ FS2D FSE TERM
GRIL LAGR LECT COQ TERM
     ALE  LECT LIQ TERM
     FS   LECT FSE TERM
COMPLEMENT EPAIS 15 LECT COQ TERM
MATE LINE RO 7.8E-9 YOUNG 190E3 NU 0.3
          LECT COQ TERM
     FLUI RO 1E-9 C 1E6
          LECT LIQ  TERM
     IMPE PIMP RO 1E-9  PRES -0.02
          TABP 3  0 0    0.002  1     1 1
          LECT ENT  TERM
     IMPE ABSO RO 1E-9 C 1E6
          LECT SOR ENT2 TERM
     IMPE GRIL RO 1E-9 C 1E6 ALP 1 TAU 0
          LECT GRI  TERM
LIAI RENUM
     BLOQ 1   LECT AXE  TERM
          1   LECT BOR  TERM
          2   LECT PCF  TERM
          3   LECT PCE PCF TERM
     FS LECT FSE TERM
IMPR FREQ 500
     TRAC ALIC 10  10
OPTI PAS AUTO
     NOTEST
CALCUL 0. 1E-5   1E-4   500   6E-3
SUITE
PLAQUE PERFOREE SOUPLE (EULER) ALP=1 TAU=0 E=15
RESULT 10
TEMPS 60 COURBE 7 TERM
SORTIE GRAPHIQUE
AXTEMPS 1E3 'T (MILLISEC.)'
COURBE  1 'P-3    '   ECROU COMP 1 ELEM  3
COURBE  2 'P-28   '   ECROU COMP 1 ELEM  28
COURBE  3 'P-48   '   ECROU COMP 1 ELEM  48
COURBE  4 'P-53   '   ECROU COMP 1 ELEM  53
COURBE  5 'P-73   '   ECROU COMP 1 ELEM  73
COURBE  6 'P-98   '   ECROU COMP 1 ELEM  98
COURBE  7 'DZ-64  '   DEPLA COMP 2 NOEU  64
DESSIN 6  1 2 3 4 5 6     AXES 10   'PRES. (BARS)'
DESSIN 1  7               AXES 1.   'DEPLA. (MM)'
FIN

Previous Up Next